Zebab.dk Sebastian Riege Warnez

Hello World!

So I had some time tonight to mess around with Box2D in flash, and I made my first Hello World application! It's not pretty, since it was made in 2 hours, but I hope you like it!

See below for the actionscript code. Note that I use symbols inside a .fla file for the sprites. You can get the .fla file here.

 
package {
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.utils.Timer;
	import flash.events.TimerEvent;
 
	import Box2D.Dynamics.*;
	import Box2D.Collision.*;
	import Box2D.Collision.Shapes.*;
	import Box2D.Common.Math.*;
 
	public class HelloWorld extends Sprite
	{
		public var the_world:b2World;
 
		// This is done since Box2D scales up by 30
		// Multiply with ps to get proper position
		public var ps:Number = 30; 
 
		//Use this function to calculate size
		public function realPixels(n:Number):Number
		{
			return (n / ps / 2);
		}
 
		public function HelloWorld()
		{
			var environment:b2AABB = new b2AABB();
			environment.lowerBound.Set(-100.0, -100.0);
			environment.upperBound.Set(100.0, 100.0);
 
			var gravity:b2Vec2=new b2Vec2(0.0, 10.0);
			the_world=new b2World(environment, gravity, true);
 
			// Create ground
			var groundW:Number = realPixels(650);
			var groundH:Number = realPixels(20);
			var groundX:Number = 300 / ps;
			var groundY:Number = 400 / ps;
 
			var bodyDef:b2BodyDef = new b2BodyDef();
			bodyDef.position.Set(groundX, groundY);
 
			var boxDef:b2PolygonDef = new b2PolygonDef();
			boxDef.SetAsBox(groundW, groundH);
			boxDef.friction = 0.3;
			boxDef.density = 0; // static
 
			bodyDef.userData = new ground();
			bodyDef.userData.width = groundW * ps * 2;
			bodyDef.userData.height = groundH * ps * 2;
			addChild(bodyDef.userData);
 
			var body:b2Body = the_world.CreateBody(bodyDef);
			body.CreateShape(boxDef);
			body.SetMassFromShapes();
 
			// Create boxes
			createBox(80, 190, 30, 30, new boxH());
			createBox(100, 150, 30, 30, new boxE());
			createBox(120, 110, 30, 30, new boxL());
			createBox(140, 70, 30, 30, new boxL());
			createBox(160, 30, 30, 30, new boxO());
 
			createBox(300, 190, 30, 30, new boxW());
			createBox(320, 150, 30, 30, new boxO());
			createBox(340, 110, 30, 30, new boxR());
			createBox(360, 70, 30, 30, new boxL());
			createBox(380, 30, 30, 30, new boxD());
 
			addEventListener(Event.ENTER_FRAME, on_enter_frame);
		}
 
		public function createBox(x:Number, y:Number, w:Number, h:Number, sprite:Sprite):void
		{
			var ww:Number = realPixels(w);
			var hh:Number = realPixels(h);
			var xx:Number = x / ps;
			var yy:Number = y / ps;			
 
			var bodyDef:b2BodyDef = new b2BodyDef();
			bodyDef.position.Set(xx, yy);
 
			var boxDef:b2PolygonDef = new b2PolygonDef();
			boxDef.SetAsBox(ww, hh);
			boxDef.friction = 0.3;
			boxDef.density = 1; // dynamic
 
			bodyDef.userData = sprite;
			bodyDef.userData.width = ww * ps * 2;
			bodyDef.userData.height = hh * ps * 2;
			addChild(bodyDef.userData);
 
			var body:b2Body = the_world.CreateBody(bodyDef);
			body.CreateShape(boxDef);
			body.SetMassFromShapes();
		}
 
		public function on_enter_frame(e:Event)
		{
			the_world.Step(1/30, 10);
 
			// Update sprites according to body
			for (var bb:b2Body = the_world.m_bodyList; bb; bb = bb.m_next) {
				if (bb.GetUserData() != null)
				{
					bb.m_userData.x = bb.GetPosition().x * ps;
					bb.m_userData.y = bb.GetPosition().y * ps;
					bb.m_userData.rotation = bb.GetAngle() * (180/Math.PI) % 360;
				}
			}
		}
	}
}